• 프리카운터
  • 플래시북
  • 프리보드
  • 전광판
  • 웹공부방
  • 커뮤니티
[asp] 썸네일 2008.07.10 22:27
글쓴이 : 운영자 조회 : 1504 추천 : 4 
안녕하심까? 
많은 분들이 asp를 통해 썸네일을 구현하고자 노력하시는데 
애석하게도 아직 asp에는 썸네일이 없거나 있는 것 역시 모두 유료라 
사용을 꺼리고 계신 것으로 알고 있습니다. 
얼마전 코드프로젝트 홈페이지를 통해 우연히 썸네일이 구현된 것을 보고 
반갑고도 좋은 정보라 이곳에 올립니다. 
자세한 내용은 직접 확인해 보시도록!! 
 
이 섬네일은 무료 이미지 콤포넌트인 Cximage.dll 을 이용해 구현 하셨더군요. 
Cximage.dll 은 코드 프로젝트 홈이나 제작자의 홈인 http://www.aoi.it 에서 
다운 받으실 수 있습니다.다운 받으셔서 Cximage.dll 을 레지스트리에 등록하시구요 
 
 
Cximage가 거의 모든 그림파일을 건드릴 수 있기 때문에 당근 이 섬네일역시 거의 모든 그림파일에 
적용하실 수 있을 겁니다. 
 
 
음~~ 아직도 믿지 못하시는 분이... 
예제 소스 보여 드립니다. 
제 컴이니까 해킹할 생각 마시구요 (암것두 없습니다.) 접속안될때는 꺼 있을 때 입니다. 
http://218.52.60.92/Thumbnail/Thumbasp/work.asp 
여기서 확인해 보세요. 
 
그럼 소스 나갑니다.!!!! 
 
 
1. ListThumbs.inc 파일 
<% 
Function IsFileOfType(afile,infile_type) 
 IsFileOfType = (UCase(Right(afile,Len(infile_type)))=UCase(infile_type)) 
End Function 
 
Sub WriteGotoPageScript 
 Response.Write "<script language=""javascript"">" & vbCrLf & _ 
 "//<!--" & vbCrLf & "function GoToPage(vpath,n) { " & vbCrLf & _ 
 "document.forms(0).hdnCurPage.value=n;" & vbCrLf & _ 
 "document.forms(0).submit(); " & vbCrLf & _ 
 "}" & vbCrLf & "//-->" & vbCrLf & "</" & "script>" & vbCrLf 
End Sub 
 
Function ListThumbs 
(VPath,Columns,Filter,AllowPaging,PageSize,Width,Height,Quality,AllowStretch,ShowFilenames,ShellThumbnail 
s) 
 Set fso = CreateObject("Scripting.FileSystemObject") 
 Set ScriptName = Request.ServerVariables("SCRIPT_NAME") 
 ScriptPath = Left(ScriptName,InstrRev(ScriptName,"/")) 
 If Right(VPath,1)<>"/" Then VPath=VPath & "/" 
 path = Server.MapPath(VPath): If Right(path,1)<>"" Then path=path & "" 
 ' analyze filter string 
 If Len(Filter)=0 Then Filter = "*.gif;*.jpg;*.bmp" 
 arSuffixes = Split(Filter,";") 
 For i=0 To UBound(arSuffixes) 
 pos=Instr(1,arSuffixes(i),".") 
 If pos>0 Then arSuffixes(i) = Mid(arSuffixes(i),pos) ' e.g. ".gif" 
 Next 
 Dim CurPage,TotalPages 
 ' -- write client script and hidden field for current page and path 
 If AllowPaging Then Call WriteGotoPageScript 
 If Len(Request.Form("hdnCurPage"))>0 Then 
 CurPage = CInt(Request.Form("hdnCurPage")) 
 Else CurPage=1 
 End If 
 Response.Write "<input type='hidden' name='hdnCurPage' value='" & CurPage & "' />" & vbCrLf 
 If Request.Form("hdnPrevPath")<> VPath Then CurPage = 1 ' restart page numbering 
 Response.Write "<input type='hidden' name='hdnPrevPath' value='" & VPath & "' />" & vbCrLf 
 
 Dim arrFilesAll(),ubn 
 If fso.FolderExists(path) Then 
 Set oFolder = fso.GetFolder(path) 
 For Each oFile in oFolder.Files 
 bFileInFilter=False 
 For i=0 To UBound(arSuffixes) 
 If IsFileOfType(oFile.Name,arSuffixes(i)) Then bFileInFilter=True 
 Next 
 If bFileInFilter Then 
 ReDim Preserve arrFilesAll(ubn) 
 arrFilesAll(ubn) = oFile.Name 
 ubn=ubn+1 
 End If ' if in filter 
 Next 
 End If 
 
 If AllowPaging Then 
 TotalPages = CInt(ubn/PageSize) 
 If ubn Mod PageSize>0 Then TotalPages = TotalPages + 1 
 if TotalPages=0 Then TotalPages=1 
 ' make sure current page is in the [1,totalPages] range 
 if CurPage>TotalPages Then 
 CurPage=TotalPages 
 else 
 if CurPage<1 Then CurPage=1 
 end if 
 ' range of files to read 
 StartIndex = (CurPage-1)*PageSize 
 EndIndex = CurPage*PageSize 
 If ubn < EndIndex Then EndIndex = ubn 
 Else 
 StartIndex = 0: EndIndex = ubn 
 End If 
 ' write thumbnail hrefs 
 If fso.FolderExists(path) Then 
 Response.Write "<TABLE ALIGN='CENTER'>" & vbCrLf 
 For index=StartIndex To EndIndex-1 
 FileName = arrFilesAll(index) 
 ' Response.write path & FileName 
 Set oFile=fso.GetFile(path & FileName) : FileSize=oFile.Size 
 nCol = nCol+1 
 VFilePath = VPath & FileName 
 sHREF = "<a href='" & VFilePath & "'>" & _ 
 "<img src='" & ScriptPath & "ThumbGenerate.asp?VFilePath=" & _ 
 Server.URLEncode(VFilePath) & "&Width=" & Width & "&Height=" & Height & "&Quality=" & Quality & _ 
 "&ShellThumbnails=" & ShellThumbnails & "&AllowStretch=" & AllowStretch & _ 
 "' border=0 alt='Name: " & FileName & "&#10;&#13;Size: " & CInt(FileSize/1024) & " Kb'/> </a>" 
 If nCol = 1 Then Response.Write "<TR>" 
 Response.Write "<TD align='Center' style='background-color:White;border-width:1px;border- 
style:Solid;font-size:8pt;'>" & vbCrLf 
 Response.Write sHREF & vbCrLf 
 If ShowFilenames Then Response.Write "<br/>" & FileName 
 Response.Write "</TD>" & vbCrLf 
 If nCol = Columns Then 
 Response.Write "</TR>" & vbCrLf 
 nCol = 0 
 End If 
 Next 
 Response.Write NumImagesDisplayed(EndIndex-StartIndex,AllowPaging,ubn,CurPage,TotalPages) 
 If AllowPaging Then 
 Response.Write CreateNavBar(VPath,CurPage,TotalPages,Columns) 
 End If 
 Response.Write "</TABLE>" & vbCrLf 
 Else 
 Response.Write "Directory Does Not Exist<P>" & vbCrLf 
 End If 
End Function 
 
Function NumImagesDisplayed(NumDisplayed,AllowPaging,TotalFiles,CurPage,TotalPages) 
 s = "<tr><td align='Center' colspan='" & Columns & "' style='background-color:#FFFFC0;font-size:8pt;'>" 
 s = s & NumDisplayed 
 if AllowPaging Then s = s & " of " & TotalFiles 
 s = s & " thumbnails" 
 if AllowPaging Then 
 s = s & " (Page " & CurPage & " of " & TotalPages & ")" 
 end if 
 s = s & "</td></tr>" 
 NumImagesDisplayed = s 
End Function 
 
Function CreateNavBar(VPath,CurPage,TotalPages,Columns) 
if TotalPages = 1 Then Exit Function 
s = "<tr><td align='Center' colspan='" & Columns & "' style='font-size:8pt;'>" 
if CurPage>1 Then 
 'GoToPage client script updates hidden field with target page 
 'and then causes a postback 
 s = s & "<A href=""javascript:GoToPage('" & VPath & "'," & CurPage-1 & _ 
 ");"">&lt;&lt; Prev</A>&nbsp;&nbsp;" 
End If 
for i=1 To TotalPages 
 if i=CurPage Then 
 s = s & "<b>" & i & "</b>" 
 else 
 s = s & "<A href=""javascript:GoToPage('" & VPath & "'," & i & ");"">" & _ 
 i & "</A>" 
 end if 
 s = s & "&nbsp;" 
 If i Mod 10=0 Then s = s & "<br/>" 
Next 
If CurPage<TotalPages Then 
 s = s & "&nbsp;<A href=""javascript:GoToPage('" & VPath & "'," & CurPage+1 & _ 
 ");"">Next &gt;&gt;</A>&nbsp;&nbsp;" 
End If 
s = s & "</td></tr>" 
CreateNavBar = s 
End Function 
 
%> 
 
2. ThumbGenerate.asp 파일 
 
 
<% 
Set fso = Server.CreateObject("Scripting.FileSystemObject") 
 
Response.ContentType = "image/jpeg" 
' ---- parameter parsing ----' 
Dim VFilePath,FilePath,Width,Height,Quality,bShellThumbnails,bStretch,bCreate 
VFilePath = Request("VFilePath") 
If Len(VFilePath)=0 Then VFilePath="NoThumb.gif" 
FilePath = Server.MapPath(VFilePath) 
If Not fso.FileExists(FilePath) Then 
 FilePath = Server.MapPath("NoThumb.gif") 
End If 
If Len(Request("Width"))>0 Then 
 Width = Int(Request("Width")) 
Else Width = 200 
End If 
If Len(Request("Height"))>0 Then 
 Height = Int(Request("Height")) 
Else Height = 200 
End If 
If Len(Request("Quality"))>0 Then 
 Quality = Int(Request("Quality")) 
Else Quality = 75 
End If 
If Len(Request("ShellThumbnails"))>0 Then 
 bShellThumbnails = (Request("ShellThumbnails")="True") 
Else bShellThumbnails = False 
End If 
If Len(Request("AllowStretch"))>0 Then 
 bStretch = (Request("AllowStretch")="True") 
Else bStretch = False 
End If 
 
Dim BinData 
If bShellThumbnails Then 
 ' Create COM Shell Thumbnail object 
 Set objThumb = Server.CreateObject("ThumbExtract.FileThumbExtract") 
 Call objThumb.SetPath(FilePath) 
 Call objThumb.SetThumbnailSize(Width,Height) 
 Call objThumb.ExtractThumbnail 
 BinData = objThumb.ThumbJpgData(Quality) 
Else 
 ' Create COM CxImage wrapper object 
 Set objCxImage = Server.CreateObject("CxImageATL.CxImage") 
 Call objCxImage.Load(FilePath,GetFileType(FilePath)) 
 Call objCxImage.IncreaseBpp(24) 
 ' determine thumbnail size and resample original image data 
 If Not bStretch Then ' retain aspect ratio 
 widthOrig = CDbl(objCxImage.GetWidth()) 
 heightOrig = CDbl(objCxImage.GetHeight()) 
 fx = widthOrig/Width 
 fy = heightOrig/Height 'subsample factors 
 ' must fit in thumbnail size 
 If fx>fy Then f=fx Else f=fy ' Max(fx,fy) 
 If f<1 Then f=1 
 widthTh = Int(widthOrig/f) 
 heightTh = Int(heightOrig/f) 
 Else 
 widthTh = Width 
 heightTh = Height 
 End If 
 Call objCxImage.Resample(widthTh,heightTh,2) 
 BinData = objCxImage.ImageForASP(2,Quality) 
End If 
 
' output in Response ' 
Response.BinaryWrite BinData 
 
Function GetFileType(sFile) 
 dot = InStrRev(sFile, ".") 
 filetype=2 
 If dot > 0 Then sExt = LCase(Mid(sFile, dot + 1, 3)) 
 If sExt = "bmp" Then filetype = 0 
 If sExt = "gif" Then filetype = 1 
 If sExt = "jpg" Then filetype = 2 
 If sExt = "png" Then filetype = 3 
 If sExt = "ico" Then filetype = 4 
 If sExt = "tif" Then filetype = 5 
 If sExt = "tga" Then filetype = 6 
 If sExt = "pcx" Then filetype = 7 
 GetFileType=filetype 
End Function 
 
%> 
 
어떻게 적용하는 지 알려 달라구요? 
그림보는 html태그에 아래와 같이 넣으시면 적용됩니다. 
아래 소스 보시면 충분히 다른 여러가지 방법으로 변형하실 수 있겠지요 흐흐~~ 
 
<!-- #include file ="./ListThumbs.inc" --> 
<img src='./ThumbGenerate.asp?VFilePath=/Thumbnail/ThumbAsp/001.gif& 
Width=50&Height=50&Quality=75' 
 border=0 alt='Name: 001.gif'/> 
 
 
인생은 짧습니다.
그러므로 다른 사람이 요구하는 삶을 살면서 시간을 낭비해서는 안 됩니다.
돈과 명예를 얻지 못하더라도 끝까지 자신의 길을 고집하십시오
목록 윗글 아랫글
내알 FREECOUNT.NET 프카넷 생긴날 2003.12.20 홈 | 카운터 | 플래시북 | 프리보드 | 전광판 | 웹공부방 | 커뮤니티 | 쪽지함