AS2.0 에서 흔히 무비클럽이나 클래스내의 객체나 하위 무비클럽을 탐색하는 방법으로 for... in의

구문을 사용하였다. 탐색후 해당 인스턴트나 하위무비클럽에 일괄, 개별적인 액션제어등의 필요에

의해서 (아주) 많이 사용했던 방법이었다.

_________________________________________________________________________________

예 : [AS2] 현재 무비클럽안에 있는 모든 하위 무비클럽의  x좌표를 0으로하고, 정지시킨다 

       여기서 this 는 무비클럽이다.

 

for(var p in this){

trace(p + "::" + this[p]);

this[p].x = 0;

this[p].stop();

}

 

_____________________________________________________________________________________

 

그런데 AS3에서 for.....in  혹은 for each ....in 등의 구문으로는 동적으로 정의된 변수나 인스턴트에

대해서 탐색이 불가능하다. 즉, 위와 같은 탐색 방법으로는 원하는 결과를 얻기 힘들다.

DisplayObjectContainer에서 제공하는 numChildren 이나 getChil~~~~등의 메소드와 프로퍼티는

등으로 얻어내는 것도 불가능하다.(화면에 addchild되지 않았으므로....... 너무 당연한가?)

AS3에서는 다음과 같이 탐색할 수 있으며, 주요메소드로 describeType을 들 수 있다.(레퍼런스 참조)

다음 예제는 해당 클래스에서 Movieclip 타입의 하위인스턴트를 찾아서 해당하는 타입이 맞으면

Dic(Dictionary 클래스)로 저장한다. 여기서 Dictionary클레스를 사용하는 이유는 weak 참조를

사용해서 수동으로 가비지 컬렉션을 제어하기 위한 목적이다.

 

_______________________________________________________________________________________

[예제 AS3.0 코드]

import flash.utils.*;

 

var description:XML = describeType(this);
var temp_obj:XMLList = description..variable;
var dic:Dictionary = new Dictionary(true);
for(var p in temp_obj){
 if(this[temp_obj[p].@name] is MovieClip){
  dic[String(temp_obj[p].@name)] = temp_obj[p];
  trace(p, "::", dic[String(temp_obj[p].@name)].@type, temp_obj[p].@name);
 }
}
_________________________________________________________________________________________

 

 

 

 

다음은 위의 코드를 조금 발전시켜서 작성해 보았다.

 

 

 

--------------------------------------------------------------------------

[UtilObject.as]

// ActionScript file
package net.Hiddenid.Utils{
/**
*  1. 파일명 : UtilObject.as
*  <p/>
*  2. 제작목적 : 객체 데이터 컨트롤 & 접근
*  <p/>
*  3. 제작자 : 유주상(Hiddenid)
*  <p/>
*  4. 제작일 : 2007.06.11 오후 10:28
*  <p/>
*  5. 최종수정일 : 2007.08.11 오후 10:28
*  <p/>
*  6. 부가설명 : 메소드 추가 및  변형 진행중. 싱글턴 패턴
*  <p/>
*  8. 사용법 :
*  <listing>
*   import net.Hiddenid.Utils.UtilObject;
*   UtilObject.getInstance().addEventListener("Event_Run", Type_Trigger);
*   UtilObject.getInstance().Manage_Object(this, ["Mc_Piece","Object"], true);
*  </listing> 
*  <p/>
*  @playerversion Flash 9.0.28.0
*   @langversion ActionScript3.0
*/ 
 import flash.display.*;
 import flash.events.*;
 import flash.utils.*;
 import net.Hiddenid.Events.Hiddenid_Event;
 public class UtilObject extends EventDispatcher {

    /**
     * 사용자 정의 이벤트 이벤트 상수 선언
     * @eventType Event_Run
     */
     public static const Trigger_Run:String = 'Event_Run';
 
    /**
     * 싱클턴 패턴. 객체 인스턴스
     */
  private static var _instance:UtilObject = null;

    /**
     * trace의 출력여부 결정
     */
  private var _trace_mode:Boolean = false;  
  public function UtilObject(target:IEventDispatcher=null):void{
   super(target);
  }
  
  public static function getInstance():UtilObject {
   if(_instance == null) _instance = new UtilObject();
   return _instance;
  }
  
  /**
   * 객체(클래스)를 검사하여 type파라미터에 선언된 타입일 경우 trace 혹은 trigger이 작동하게 된다.
   *
   * @param object 검토하려는 오브젝트(혹은 클래스)
   * @param type 검토 중 배열에 속한 타입일때만  trace혹은 trigger작동
   * @param trigger 검토 중 작동할 trigger.
   *
   */  
  public function Manage_Object(object:*, type:Array = null, trigger:Boolean = false):void{

   var description:XML = describeType(object);
   var Xml_Refer:XMLList = description..variable;
   var dic:Dictionary = new Dictionary(true);
   try{    
    for (var p:String in Xml_Refer){
     var temp_p:String = Xml_Refer[p]["@type"];
     var ttt = Xml_Refer[p];
     for(var i:int = 0 ; i < type.length ; i++){
      //if(getQualifiedClassName(Xml_Refer[p]) is getQualifiedClassName(type[i])&& type){
      if((getDefinitionByName(temp_p) == getDefinitionByName(type[i].toString()))&& type != null){
       this._trace_mode == true ? trace(getQualifiedSuperclassName(getDefinitionByName(type[i].toString())) , ":객체출력:",type[i] , p, getDefinitionByName(temp_p)) : null;
       dic[String(Xml_Refer[p]["@name"])] = Xml_Refer[p];
      }else{
       if(type == null && this._trace_mode == true){
        trace(":모든객체 체크:",p);
       }
      }
     }

    }
   }catch(e:Error){
    trace( "체크타입::",getDefinitionByName(temp_p), ">>UtilObject_60_에러발생::", e);
   }
 
   try{
    if(trigger == true){
     dispatchEvent(new Hiddenid_Event(Hiddenid_Event.Trigger_Run, dic)); 
    }
   }catch(e:Error){
    trace("UtilObject_Line:88_에러발생::" + e);
   }
  
  }
  
  //Get, Setter 선언시작_______________________________________________________________________
  /*
   객체 trace 메세지 출력여부 결정
  */
 
     /**
      * trace여부 결정
      */  
     public function get trace_mode():Boolean{
         return this._trace_mode;
     }
 
     /**
      * @private (setter)
      */
  public function set trace_mode(mode:Boolean):void{
   this._trace_mode = mode;
  }
  
  //Get, Setter 선언끝_________________________________________________________________________  
  
 }
}

----------------------------------------------------------------------------

 

 

 

___________________________________________________________________________________

 

[위에서 사용하는 사용자 Event클래스]

 

[HIddenid_Event.as]

 

 

// Copyright � 2007. Adobe Systems Incorporated. All Rights Reserved.
package net.Hiddenid.Events
{
import flash.events.Event;
import flash.utils.Dictionary;

/**
 * Hiddenid_Event 클래스는 사용자 정의 이벤트 클래스로, Dictionary클래스에 사용자 정의 파라미터를 담기 위한 목적으로 쓰인다.
 * @playerversion Flash 9
 * @langversion 3.0
 * @keyword Tween event   
 * @see fl.transitions.Tween
 */
public class Hiddenid_Event extends Event
{
    /**
    *  트리거 혹은 Hiddenid 이벤트 발생...... 실행 시작을 표현
     * Indicates that the motion has started playing.
     *  <p>The properties of the event object have the following values:</p>
     *  <table class="innertable">
     *     <tr><th>Property</th><th>Value</th></tr>
     *     <tr><td><code>bubbles</code></td><td>false</td></tr>
     *     <tr><td><code>cancelable</code></td><td>false</td></tr>
     *     <tr><td><code>currentTarget</code></td><td>현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체. </td></tr>
     *     <tr><td><code>target</code></td><td>이벤트 대상</td></tr>
     *     <tr><td><code>_dictionary</code></td><td>target에 전달된 파라미터 정보를 담고 있는 Dictionary객체</td></tr>
     *  </table>
     * @playerversion Flash 9
     * @langversion 3.0
     * @keyword Hiddenid Event
     * @eventType Event_Run
     */
    public static const Trigger_Run:String = 'Event_Run';

 /**
  * 해당 이벤트 청취 함수가 전달받게 되는 데이터 딕셔너리. 모든 변수 담는다. 가비지 컬랙션 수동관리를 위해 약한참조 사용
     *
     * @playerversion Flash 9
     * @langversion 3.0
     * @keyword Hiddenid Event
     */
 public var _dictionary:Dictionary = new Dictionary(true);
 

  /**
  *  Constructor function for a TweenEvent object.
  *
  *  @param type 이벤트타입; 일어날 사용자 이벤트 액션을 가르킨다.indicates the action that caused the event.
  *  @param dic 이벤트 액션에 전달된 Dictionary인스턴트
  *  @param bubbles 이벤트가 버블링 이벤트인지 여부를 나타낸다. 이 값은 이벤트가 버블링 가능한 경우 true이고, 그렇지 않으면 false이다.
  *  @param cancelable 해당 이벤트와 연관된 비헤이비어를 차단할 수 있는지 여부를 나타낸다.
     *
     * @playerversion Flash 9
     * @langversion 3.0
     * @keyword Tween event      
     */    
 public function Hiddenid_Event(type:String, dic:Dictionary = null, bubbles:Boolean=false, cancelable:Boolean=false)
 {
  super(type, bubbles, cancelable);
  this._dictionary = dic;
 }

 /**
  *  @private
  */
 override public function clone():Event
 {
  return new Hiddenid_Event(this.type, this._dictionary, this.bubbles, this.cancelable);
 }
}
}